Программно открыть форму внешней обработки в управляемом приложении

07.12.2016 16:43

26370

Открытие формы внешней обработки через создание объекта обработки.

&НаКлиенте
Процедура Команда(Команда)
	КомандаНаСервере();
	ОткрытьФорму("ВнешняяОбработка.Обработка.Форма");
КонецПроцедуры

&НаСервере
Процедура КомандаНаСервере()
	Обработка = ВнешниеОбработки.Создать("C:\Users\Администратор\Desktop\Обработка.epf");
КонецПроцедуры

Открытие формы внешней обработки через временное хранилище.

Чтобы открыть форму внешней обработки в управляемом приложении нужно загрузить файл обработки во временное хранилище.
Если свойство Конфигурации "РежимИспользованияМодальности" установлено в значение "Использовать", то можно применить глобальный метод "ПоместитьФайл()". Если свойство установлено в значение "НеИспользовать", то будет работать только метод "НачатьПомещениеФайла()".

Когда РежимИспользованияМодальности = Использовать

&НаКлиенте
Процедура КомандаНажатиеНаКнопку(ПараметрКоманды, ПараметрыВыполненияКоманды)

	АдресФайла = "C:\Users\Администратор\Desktop\Обработка.epf";	
	
	АдресХранилища = "";
	ПоместитьФайл(АдресХранилища, АдресФайла,,Ложь);
	ИмяОбработки = ПодключитьВнешнююОбработку(АдресХранилища);
	ОткрытьФорму("ВнешняяОбработка." + ИмяОбработки + ".Форма");
	
КонецПроцедуры

&НаСервере
Функция ПодключитьВнешнююОбработку(АдресХранилища)
	Возврат ВнешниеОбработки.Подключить(АдресХранилища);	
КонецФункции

Когда РежимИспользованияМодальности = Не использовать

&НаКлиенте
Процедура КомандаНажатиеНаКнопку(ПараметрКоманды, ПараметрыВыполненияКоманды)

	АдресФайла = "C:\Users\Администратор\Desktop\Обработка.epf";	
	
	Оповещение = Новый ОписаниеОповещения("Оповещение", ЭтотОбъект);
	НачатьПомещениеФайла(Оповещение,, АдресФайла, Ложь);
			
КонецПроцедуры

&НаКлиенте
Процедура Оповещение(Результат, Адрес, ВыбранноеИмяФайла, ДополнительныеПараметры) Экспорт
	ИмяОбработки = ПодключитьВнешнююОбработку(Адрес);
	ОткрытьФорму("ВнешняяОбработка." + ИмяОбработки + ".Форма");
КонецПроцедуры

&НаСервере
Функция ПодключитьВнешнююОбработку(АдресХранилища)
	Возврат ВнешниеОбработки.Подключить(АдресХранилища);	
КонецФункции

Комментарии (0)