В ячейку элемента формы "ПолеТабличногоДокумента" добавить флажок, кнопку, поле ввода

В ячейки элемента формы "ПолеТабличногоДокумента" можно вставить элементы управления (флажок, кнопка, поле ввода, и.т.д). В палитре свойств доступно добавление поля ввода и флажка. Программным способом возможно добавление любого элемента управления.

Добавление поля ввода в палитре свойств

Результат добавления элемента управления в ячейку

Программное добавление элементов

Процедура ДобавлениеЭлементовУправления(Кнопка)
		
	ПолеТабДок = ЭлементыФормы.ПолеТабличногоДокумента;	
	
	//Установить флажок
	Массив = Новый Массив; 
	Массив.Добавить(Тип("Булево"));
	ОписаниеТипов = Новый ОписаниеТипов(Массив);
					  
	ПолеТабДок.Область("R1C1").СодержитЗначение = Истина;
	ПолеТабДок.Область("R1C1").ТипЗначения = ОписаниеТипов;
	ПолеТабДок.Область("R1C1").Значение = Ложь;
	ПолеТабДок.Область("R1C1").УстановитьЭлементУправления(Тип("Флажок"));

	//Установить поле ввода 
	Массив = Новый Массив; 
	Массив.Добавить(Тип("СправочникСсылка.Справочник1"));
	ОписаниеТипов = Новый ОписаниеТипов(Массив);
	
	ПолеТабДок.Область("R1C2").СодержитЗначение = Истина;
	ПолеТабДок.Область("R1C2").ТипЗначения = ОписаниеТипов;	
	ПолеТабДок.Область("R1C2").УстановитьЭлементУправления(Тип("ПолеВвода"));
	
	Поле = ПолеТабДок.Область("R1C2").ЭлементУправления;
	Поле.КнопкаВыбора = Истина;
	
	//Установить кнопку 
	ПолеТабДок.Область("R1C3").СодержитЗначение = Истина;	
	ПолеТабДок.Область("R1C3").УстановитьЭлементУправления(Тип("Кнопка"));
	
	Кнопка = ПолеТабДок.Область("R1C3").ЭлементУправления;
	Кнопка.Заголовок = "Выполнить";
	Кнопка.УстановитьДействие("Нажатие", Новый Действие("ВыполнитьНажатие"));
	
КонецПроцедуры


Процедура ВыполнитьНажатие(Кнопка)
	Сообщить("нажатие кнопки");
КонецПроцедуры 

Результат добавления элементов управления в ячейки